Package Ground Zero investor demo

2026-05-14 00:51:47 -07:00
parent 6d25ff690d
commit 1eb752536c
10 changed files with 303 additions and 10 deletions
@@ -0,0 +1,61 @@
+@echo off
+setlocal
+
+set "PROJECT_DIR=%~dp0.."
+set "PROJECT_FILE=%PROJECT_DIR%\AgrarianGame.uproject"
+set "UE_ROOT=C:\Program Files\Epic Games\UE_5.7"
+set "RUN_UAT=%UE_ROOT%\Engine\Build\BatchFiles\RunUAT.bat"
+set "ARCHIVE_DIR=%PROJECT_DIR%\Builds\WindowsDevelopment"
+set "LOG_DIR=%PROJECT_DIR%\Saved\BuildLogs"
+set "LOG_FILE=%LOG_DIR%\PackageWindowsDevelopment.log"
+
+if not exist "%LOG_DIR%" mkdir "%LOG_DIR%"
+if not exist "%ARCHIVE_DIR%" mkdir "%ARCHIVE_DIR%"
+
+if not exist "%RUN_UAT%" (
+  echo Unreal Engine 5.7 RunUAT was not found at:
+  echo %RUN_UAT%
+  exit /b 1
+)
+
+if not exist "%PROJECT_FILE%" (
+  echo Project file was not found at:
+  echo %PROJECT_FILE%
+  exit /b 1
+)
+
+echo Packaging Agrarian Windows Development build...
+echo Archive: %ARCHIVE_DIR%
+echo Log: %LOG_FILE%
+
+call "%RUN_UAT%" BuildCookRun ^
+  -project="%PROJECT_FILE%" ^
+  -noP4 ^
+  -platform=Win64 ^
+  -clientconfig=Development ^
+  -build ^
+  -cook ^
+  -stage ^
+  -pak ^
+  -archive ^
+  -archivedirectory="%ARCHIVE_DIR%" ^
+  -map=/Game/Agrarian/Maps/L_GroundZeroTerrain_Test+/Game/ThirdPerson/Lvl_ThirdPerson ^
+  -prereqs ^
+  -utf8output ^
+  -NoUBA > "%LOG_FILE%" 2>&1
+
+set "PACKAGE_EXIT_CODE=%ERRORLEVEL%"
+type "%LOG_FILE%"
+
+if not "%PACKAGE_EXIT_CODE%"=="0" (
+  echo.
+  echo Package failed with exit code %PACKAGE_EXIT_CODE%.
+  echo Log file: %LOG_FILE%
+  exit /b %PACKAGE_EXIT_CODE%
+)
+
+echo.
+echo Package completed successfully.
+echo Archive: %ARCHIVE_DIR%
+echo.
+exit /b 0